scad/pressfit_headband.scad

$fn=360;
DEBUG=false;
SIZE=60;
HEIGHT=4.6;
THICKNESS=3;
PART=0.7;
STRETCH_LEN=40;
TIP_LEN=0.05;
TIP_BEND=20;
RAKE_DEPTH=1;
RAKE_WIDTH=1;
RAKE_STRETCH=1;
RAKE_CHAMPFER=0.5;

module inserticle() {
    cube([4.6, 7.4, 5.4], center=true);
}

module testblock_inserticle() {
    union() {
        translate([0, 0, 5.4/2]) inserticle();
        translate([0, 0, -5]) cube([15, 12, 10], center=true);
    }
}

module testblock_recepticle() {
    rotate(180, [0, 1, 0]) difference() {
        translate([0, 0, 5]) cube([15, 12, 10], center=true);
        translate([0, 0, 5.4/2]) inserticle();
    }
}

module catear(height, thickness, fractal=0, side_len=30, bend_factor=0.5, stretch_factor=1.2, debug=false) {
    $A=[0, side_len/2];
    $B=[0,-side_len/2];
    $C=[-(side_len/2/sin(120))*1.5*stretch_factor, 0];
    $c=sqrt(pow($A.x-$B.x, 2)+pow($A.y-$B.y, 2));
    $b=sqrt(pow($A.x-$C.x, 2)+pow($A.y-$C.y, 2));
    $a=sqrt(pow($C.x-$B.x, 2)+pow($C.y-$B.y, 2));
    $hc=-$C.x;
    $alpha=asin($hc/$b);
    $beta=$alpha;
    $gamma=180-$alpha-$beta;
    $delta=180*bend_factor;
    $bend_radius=$a/(2*cos(90-$delta/2));
    $bend_offset=$bend_radius*sin(90-$delta/2);

    translate([0, -$c/2, 0])
      rotate($beta, [0, 0, 1])
        translate([0, $a/2, 0])
          translate([$bend_offset, 0, 0])
            color("#00ffff") partial_ring(
              part=$delta/360,
              radius=$bend_radius,
              thickness=thickness,
              height=height
            );
    translate([0, $c/2, 0])
      rotate(-$alpha, [0, 0, 1])
        translate([0, -$b/2, 0])
          translate([$bend_offset, 0, 0])
            color("#ff00ff") partial_ring(
              part=$delta/360,
              radius=$bend_radius,
              thickness=thickness,
              height=height
            );
    translate($A) color("#aaaaaa") cylinder(h=height, d=thickness, center=true);
    translate($B) color("#bbbbbb") cylinder(h=height, d=thickness, center=true);
    translate($C) color("#cccccc") cylinder(h=height, d=thickness, center=true);

    if (debug) {
      echo("A", $A, "a", $a, "alpha", $alpha);
      echo("B", $B, "b", $b, "beta ", $beta);
      echo("C", $C, "c", $c, "gamma", $gamma);
      echo("bend_factor", bend_factor);
      echo("delta:", $delta);
      echo("bend_radius", $bend_radius);
      echo("bend_offset", $bend_offset);
      color("#000000") cylinder(h=4, d=4);
      translate($C/2) color("red") cube([$hc, thickness, height*1.1], center=true);
      color("red") cube([thickness, $c, height*1.1], center=true);
      color("red")translate([0, $c/2, 0]) rotate(-$alpha, [0, 0, 1]) translate([0, -$b/2, 0])  cube([thickness, $b, height*1.1], center=true);
      color("red")translate([0, -$c/2, 0]) rotate($beta, [0, 0, 1]) translate([0, $a/2, 0])  cube([thickness, $a, height*1.1], center=true);
    }
}

module partial_ring(part, radius, thickness, height) {
    rotate(180-180*part, [0, 0, 1])
        rotate_extrude(angle=360*part)
            translate([radius, 0])
                square([thickness, height], center=true);
}

module headband(debug=DEBUG, size=SIZE, height=HEIGHT, thickness=THICKNESS, part=PART, stretch_len=STRETCH_LEN, tip_len=TIP_LEN, tip_bend=TIP_BEND, rake_depth=RAKE_DEPTH, rake_width=RAKE_WIDTH, rake_stretch=RAKE_STRETCH, rake_champfer=RAKE_CHAMPFER) {
    union() {
        color("purple") partial_ring(part, radius=size, thickness=thickness, height=height);
        rotate( 90-180*part, [0, 0, 1]) translate([stretch_len/2,  size, 0]) {
            color("orange") cube([stretch_len, thickness, height], center=true);
            color("purple") translate([stretch_len/2, tip_bend, 0])
                rotate(90+180*tip_len, [0, 0, 1])
                    partial_ring(
                        part=tip_len,
                        radius=tip_bend,
                        thickness=thickness,
                        height=height
                    );
        }
        rotate(-90+180*part, [0, 0, 1]) translate([stretch_len/2, -size, 0]) {
            color("orange") cube([stretch_len, thickness, height], center=true);
            color("purple") scale([1, -1, 1]) translate([stretch_len/2, tip_bend, 0])
                rotate(90+180*tip_len, [0, 0, 1])
                    partial_ring(
                        part=tip_len,
                        radius=tip_bend,
                        thickness=thickness,
                        height=height
                    );
        }
        for (i=[-size/2:size/2]) {
            rotate(i*2-rake_width/2, [0, 0, 1]) intersection() {
                scale([1, 1, rake_stretch/(rake_depth/height)])
                    translate([0, rake_width/2, 0]) rotate_extrude(angle=rake_width)
                        translate([rake_depth/2-size+thickness/2, 0, 0])
                            scale([1, 0.5, 1])
                                circle(r=rake_depth, $fn=3);
                translate([rake_depth/2-size+thickness/2-rake_champfer, 0, 0])
                    color("red")
                        cube([2*rake_depth, rake_width, height], center=true);
            }
        };
    };
}

module pressfit_headband(debug=DEBUG, size=SIZE, height=HEIGHT, thickness=THICKNESS, part=PART, stretch_len=STRETCH_LEN, tip_len=TIP_LEN, tip_bend=TIP_BEND) {
    union() {
        color("pink") { $a=48;
            rotate( $a, [0, 0, 1]) {
                translate([-size-4, 0,]) rotate(90, [0, 1, 0]) inserticle();
                translate([-size-3, 0,]) rotate(90, [0, 1, 0]) inserticle();
            }
            rotate(-$a, [0, 0, 1]) {
                translate([-size-4, 0,]) rotate(90, [0, 1, 0]) inserticle();
                translate([-size-3, 0,]) rotate(90, [0, 1, 0]) inserticle();
            }
        }
        headband(
            size=size,
            height=height,
            thickness=thickness,
            part=part,
            stretch_len=stretch_len,
            tip_len=tip_len,
            tip_bend=tip_bend
        );
    };
}

module catear_headband(debug=DEBUG, size=SIZE, height=HEIGHT, thickness=THICKNESS, part=PART, stretch_len=STRETCH_LEN, tip_len=TIP_LEN, tip_bend=TIP_BEND, ear_scale=1.4, ear_bend_factor=0.15, ear_stretch_factor=1, ear_angle=42) {
  union() {
    rotate( ear_angle, [0, 0, 1]) {
      translate([-size, 0, 0]) catear(
        debug=debug,
        height=height,
        thickness=thickness,
        side_len=size/2*ear_scale,
        bend_factor=ear_bend_factor,
        stretch_factor=ear_stretch_factor
      );
    }
    rotate(-ear_angle, [0, 0, 1]) {
      translate([-size, 0, 0]) catear(
        debug=false,
        height=height,
        thickness=thickness,
        side_len=size/2*ear_scale,
        bend_factor=ear_bend_factor,
        stretch_factor=ear_stretch_factor
      );
    }
    headband(
      size=size,
      height=height,
      thickness=thickness,
      part=part,
      stretch_len=stretch_len,
      tip_len=tip_len,
      tip_bend=tip_bend
    );
  };
}

module bunnyear_headband(debug=DEBUG, size=SIZE, height=HEIGHT, thickness=THICKNESS, part=PART, stretch_len=STRETCH_LEN, tip_len=TIP_LEN, tip_bend=TIP_BEND, ear_scale=0.5, ear_bend_factor=0.2, ear_stretch_factor=10, ear_angle=30) {
  catear_headband(
    debug=debug,
    size=size,
    height=height,
    thickness=thickness,
    part=part,
    stretch_len=stretch_len,
    tip_len=tip_len,
    tip_bend=tip_bend,
    ear_scale=ear_scale,
    ear_bend_factor=ear_bend_factor,
    ear_stretch_factor=ear_stretch_factor,
    ear_angle=ear_angle);
}

module foxear_headband(debug=DEBUG, size=SIZE, height=HEIGHT, thickness=THICKNESS, part=PART, stretch_len=STRETCH_LEN, tip_len=TIP_LEN, tip_bend=TIP_BEND, ear_scale=1.2, ear_bend_factor=0.01, ear_stretch_factor=1.2, ear_angle=30) {
  catear_headband(
    debug=debug,
    size=size,
    height=height,
    thickness=thickness,
    part=part,
    stretch_len=stretch_len,
    tip_len=tip_len,
    tip_bend=tip_bend,
    ear_scale=ear_scale,
    ear_bend_factor=ear_bend_factor,
    ear_stretch_factor=ear_stretch_factor,
    ear_angle=ear_angle);
}

headband();